demotool/shaders/lib/shading-pbr.glsl

//! type library
//! include lib/utils.glsl


struct T_PBRMaterial
{
	vec3 cAlbedo;
	float roughness;
	float metallic;
	float subsurface;
	float anisotropy;
	float specular;		// Specular strengh for non-metals
	float specularTint;	// Albedo color% in specular tint (non-metals)
};

// -----------------------------------------------------------------------------

float PBR_SchlickFresnel(
	in float u )
{
	const float m = clamp( 1 - u , 0 , 1 ) ,
	      m2 = m * m;
	return m2 * m2 * m;
}

float PBR_GTR2Aniso(
	in float nDotH ,
	in float hDotX ,
	in float hDotY ,
	in float ax ,
	in float ay )
{
	float x = hDotX / ax , y = hDotY / ay ,
		p = x * x + y * y + nDotH * nDotH;
	return 1 / ( PI * ax * ay * p * p );
}

float PBR_SmithGGXAniso(
	in float nDotV ,
	in float vDotX ,
	in float vDotY ,
	in float ax ,
	in float ay )
{
	float x = vDotX * ax , y = vDotY * ay;
	return 1 / ( nDotV + sqrt( x * x + y * y + nDotV * nDotV ) );
}

vec3 PBR_Shade(
	in T_PBRMaterial material ,
	in vec3 camDir ,
	in vec3 normal ,
	in vec3 lightDir )
{
	float nDotL = dot( normal , lightDir ) ,
		nDotV = dot( normal , camDir );
	if ( nDotL < 0 || nDotV < 0 ) {
		return vec3( 0 );
	}

	vec3 tangent = cross( vec3( 0 , 1 , 0 ) , normal );
	if ( length( tangent ) == 0 ) {
		tangent = cross( vec3( 1 , 0 , 0 ) , normal );
	}
	tangent = normalize( tangent );
	vec3 bitangent = normalize( cross( normal , tangent ) );

	vec3 halfVec = normalize( lightDir + camDir ) ,
		tint = M_NormalizeColor( material.cAlbedo ) ,
		cSpecular = mix( material.specular * .08 * mix(
				vec3( 1 ) , tint , material.specularTint ) ,
			material.cAlbedo , material.metallic );
	//vec3 Csheen = mix(vec3(1), Ctint, sheenTint);

	float nDotH = dot( normal , halfVec ) ,
		lDotH = dot( lightDir , halfVec ) ,

	// Diffuse fresnel - go from 1 at normal incidence to .5 at grazing
	// and mix in diffuse retro-reflection based on roughness
		FL = PBR_SchlickFresnel( nDotL ) ,
		FV = PBR_SchlickFresnel( nDotV ) ,
		Fd90 = 0.5 + 2 * lDotH * lDotH * material.roughness ,
		Fd = mix( 1 , Fd90 , FL ) * mix( 1 , Fd90 , FV ) ,

	// Based on Hanrahan-Krueger brdf approximation of isotropic bssrdf
	// 1.25 scale is used to (roughly) preserve albedo
	// Fss90 used to "flatten" retroreflection based on roughness
		Fss90 = lDotH * lDotH * material.roughness ,
		Fss = mix( 1 , Fss90 , FL ) * mix( 1 , Fss90 , FV ) ,
		ss = 1.25 * ( Fss * ( 1 / ( nDotL + nDotV ) - .5 ) + .5 ) ,

	// Specular
		aspect = sqrt( 1 - material.anisotropy * .9 ) ,
		rsqr = material.roughness * material.roughness ,
		ax = max( .001, rsqr / aspect ) ,
		ay = max( .001, rsqr * aspect ) ,
		Ds = PBR_GTR2Aniso( nDotH , dot( halfVec , tangent ) ,
				dot( halfVec , bitangent ) , ax , ay ) ,
		FH = PBR_SchlickFresnel( lDotH ) ,
		Gs  = PBR_SmithGGXAniso( nDotL , dot( lightDir , tangent ) ,
				dot( lightDir , bitangent ) , ax , ay )
			* PBR_SmithGGXAniso( nDotV , dot( camDir , tangent ) ,
					dot( camDir , bitangent ) , ax , ay );

	vec3 Fs = mix( cSpecular , vec3(1) , FH );
	return nDotL * ( ( ( 1 / PI )
			* mix( Fd , ss , material.subsurface )
			* material.cAlbedo /* + Fsheen */)
			* pow( 1 - material.metallic , 3 )
		+ clamp( Gs , 0 , 1 ) * Fs * Ds );
}